RDOAction object

set Session = CreateObject("Redemption.RDOSession")
Session.Logon
set Mail = Session.GetDefaultFolder(olFolderOutbox).Items.Add("IPM.Note")
Mail.Subject = "test Redemption action"
Mail.Body = "test body"
Mail.Recipients.Add "user@domain.com"
set action = Mail.Actions.Add
action.name = "Test respond"
action.copylike = olRespond
action.enabled = true
action.messageclass = "IPM.Note"                    'the message class to be used when the action is invoked
action.prefix = "TEST"                                        'Subject prefix
action.ReplyStyle = olEmbedOriginalItem          'original message will be embedded
action.ResponseStyle = olPrompt                        'prompt when the action is invoked
action.ShowOn = olMenuAndToolbar                 'show the action on both the popup menu and the Inspector toolbar
Mail.Send

Derived from: IDispatch

Properties

CopyLike

rdoActionCopyLike, read-write. Returns or sets the property inheritance style to use for the action. Can be one of the following rdoActionCopyLike constants:

olReply (0) - the new message will be similar to a reply to the original item.

olReplyAll (1) - the new message will be similar to a reply to all of the senders/recipients of the original item.
olForward (2) - the new message will be similar to a forward of the original item.
olReplyFolder (3) - the new message will be similar to a post to folder.
olRespond (4) - used for voting button actions

See example above

Enabled

Boolean, read/write. TRUE is the action is enabled, FALSE is disabled.

'Send a message with the "Forward" action disabled

set Session = CreateObject("Redemption.RDOSession")
Session.MAPIOBJECT = Application.Session.MAPIOBJECT
set Mail = Session.GetDefaultFolder(olFolderOutbox).Items.Add("IPM.Note")
Mail.Subject = "test Redemption action"
Mail.Body = "test body"
Mail.Recipients.Add "dmitry@dimastr.com"
set ForwardAction = Mail.Actions.Item("Forward")
if not (ForwardAction is Nothing) Then
  ForwardAction.Enabled = false
End If
Mail.Subject = "No forwarding!"
Mail.Body = "Important message, please do not forward!"
Mail.Send

MessageClass

String, read/write. Returns or sets the message class of the new item created by the action.

Name

String, read/write. Returns or sets the name of the action.

Prefix

String, read/write. Returns or sets the subject prefix (e.g. "Re" or "FW") of the new item created by the action.

ReplyStyle

rdoActionReplyStyle, read/write. Returns or sets the text formatting reply style of the action. Can be one of the following rdoActionReplyStyle constants:

olOmitOriginalText (0) - the reply will not any references to the original item or its text.
olEmbedOriginalItem (1) - the reply will include the original message as an embedded message attachment.
olIncludeOriginalText (2) - the reply will include the text of the original message.
olIndentOriginalText (3) - the reply will include the indented text of the original message.
olLinkOriginalItem (4) -the reply will include a link to the original message.
olUserPreference (5) - the reply will be based on thee user preference.
olReplyTickOriginalText (1000) - the reply will include the original text with each line preceded by ">".

ResponseStyle

rdoActionResponseStyle, read/write. Returns or sets the response style used when the action is executed. Can be  one of the following rdoActionResponseStyle constants:

olOpen (0) - the form will be opened for the user to edit the response.
olSend (1) - the reply will be sent immediately
olPrompt (2) - the user will be prompted to open or send the reply message.

ShowOn

rdoActionShowOn, read/write. Returns or sets the location where the action will be shown. Can be one of the rdoActionShowOn constants:

olDontShow (0) -will not be displayed on the menu or the toolbar
olMenu (1) - the action will be shown as an available action on the menu
olMenuAndToolbar (2) -the action will be shown as an available action on the menu and the toolbar.

Methods

Delete

Deletes the action from the message.